当前位置：物业房屋租赁管理系统平台 > 租房子 >

delphi中的“DLL里面封装了子窗”的成熟调用方法

时间：2012-12-03 08:40    来源：未知    作者：admin    点击： 次

像dll中的窗体一般用模态窗体,这样其内存比较容易控制,而不要交给其主属性如application等处理,做个小例子供你参考一下:(已调试,运行ok)

unit DLLForm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TfrmDLL = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }

  end;

var
  frmDLL: TfrmDLL;

  procedure SynAPP(App:THandle);stdcall;
  procedure ShowForm;stdcall;

implementation

uses Math;

{$R *.dfm}

procedure SynAPP(App:THandle );stdcall;
begin
  Application.Handle := App;
end;

procedure ShowForm;stdcall;
begin
  try
    frmDLL := TfrmDLL.Create (Application);
    try
      frmDLL.ShowModal;
    finally
      frmDLL.Free;
    end;
  except
    on E: Exception do
      MessageDlg ('Error in DLLForm: ' +
        E.Message, mtError, [mbOK], 0);
  end;
end;

procedure TfrmDLL.Button1Click(Sender: TObject);
begin
  Color := RandomRange(0,255 * 255 * 255 ); 
end;

end.
*************************************************

library FormDLL;

{ Important note about DLL memory management: ShareMem must be the
  first unit in your library's USES clause AND your project's (select
  Project-View Source) USES clause if your DLL exports any procedures or
  functions that pass strings as parameters or function results. This
  applies to all strings passed to and from your DLL--even those that
  are nested in records and classes. ShareMem is the interface unit to
  the BORLNDMM.DLL shared memory manager, which must be deployed along
  with your DLL. To avoid using BORLNDMM.DLL, pass string information
  using PChar or ShortString parameters. }

uses
  SysUtils,
  Classes,
  Forms,
  DLLForm in 'DLLForm.pas' {frmDLL};


{$R *.res}

exports
  SynAPP,ShowForm;

begin
end.

****************************************************************

unit testDLLForm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

procedure SynAPP(App:THandle);stdcall;external 'FormDLL.dll';
procedure ShowForm;stdcall;external 'FormDLL.dll';

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  SynApp(Application.Handle ); 
  ShowForm ;
end;

end.